on *:FILERCVD:*:{
  var %exists, %filename, %filename_left, %filename_right, %finalfilename, %i = 1, %tmpuploadfile
  if (%uploadfiles > 0) {
    %filename = $nopath($filename)
    if (%uploadfiles == 2) {
      %tmpuploadfile = $?!="Do you want to upload the file %filename sent by $nick $+ "
      if (%tmpuploadfile == $false) { halt }
    }
    %exists = $read(files_uploaded.txt,wt,%filename)
    if (%exists != $null) {
      if ($pos(%filename,.,0) == 0) {
        %filename_left = %filename
        %filename_right = $null
      }
      else {
        %filename_left = $left(%filename,$calc($pos(%filename,.,$pos(%filename,.,0))-1))
        %filename_right = $right(%filename,$calc($len(%filename)-$pos(%filename,.,$pos(%filename,.,0))))
      }
      while (%exists != $null) {
        %finalfilename = %filename_left $+ ( $+ %i $+ ). $+ %filename_right
        %exists = $read(files_uploaded.txt,wt,%finalfilename)
        %i = %i + 1
      }
    }
    else {
      %finalfilename = %filename
    }
    write -c upload_file.txt open %uploadhost
    write upload_file.txt %uploaduser
    write upload_file.txt %uploadpass
    write upload_file.txt binary
    write upload_file.txt cd %uploaddir
    write upload_file.txt put $filename %finalfilename
    write upload_file.txt quit
    run -n ftp -s:upload_file.txt
    .notice $nick The file  $+ %filename $+  is been uploaded to  $+ %url $+ $urlencode(%finalfilename) $+ 
    write files_uploaded.txt %finalfilename
    echo 4 -s The file  $+ %filename $+  is been uploaded to  $+ %url $+ $urlencode(%finalfilename) $+ 
  }
}

alias autoupload {
  if ($1 == ask || $1 == 2) {
    set %uploadfiles 2
    echo 7 -a $timestamp You will be asked for uploads now.
  }
  elseif ($1 == on || $1 == yes || $1 == 1) {
    set %uploadfiles 1
    echo 3 -a $timestamp Files will be uploaded automatically now.
  }
  elseif ($1 == off || $1 == no || $1 == 0) {
    set %uploadfiles 0
    echo 4 -a $timestamp No files will be uploaded now.
  }
  else {
    if (%uploadfiles == 0) { echo 4 -a $timestamp No files will be uploaded now. }
    elseif (%uploadfiles == 1) { echo 3 -a $timestamp Files will be uploaded automatically now. }
    elseif (%uploadfiles == 2) { echo 7 -a $timestamp You will be asked for uploads now. }
  }
}

alias -l urlencode {
  var %temp = $1-, %output = $null, %i = 1
  %len = $len(%temp)
  while (%i <= %len) {
    %asc = $asc($mid(%temp, %i, 1))
    if ((%asc >= 65 && %asc <= 90) || (%asc >= 65 && %asc <= 90) || (%asc >= 97 && %asc <= 122) || (%asc >= 48 && %asc <= 57) || %asc == 46 || %asc == 45 || %asc == 95) { %chr = $chr(%asc) }
    else { %chr = $chr(37) $+ $base(%asc, 10, 16) }
    %output = %output $+ %chr
    inc %i 1
  }
  return %output
}